ATBD for EUMETSAT Demonstration Prime GSICS Corrections for Meteosat-SEVIRI

|  |  |  |
| --- | --- | --- |
|  |  |  |
| EUMETSATEumetsat-Allee 1, D-64295 Darmstadt, GermanyTel: +49 6151 807-7Fax: +49 6151 807 555http://www.eumetsat.int |  |  |
| Doc.No. | : | EUM/RSP/TEN/14/777892 |
| Issue | : | v1C Draft |
| Date | : | 10 December 2015 |
| WBS/DBS | : |   |

Document Signature Table

|  | Name | Function | Signature | Date |
| --- | --- | --- | --- | --- |
| Prepared by: | Tim Hewison | Calibration Team Leader |  |  |
| Reviewed by | Christopher Hanson | Competence Area Manager for INRC |  |  |
| Reviewed by: | Beatriz Mora | TSS QA |  |  |
| Approved by: | Kenneth Holmlund | Head of Remote Sensing and Products Division |  |  |

Distribution List

| Name | Organisation |
| --- | --- |
| RSP/KTH, PRS/BMo, RSP/CH, RSP/TJH | EUMETSAT |
|  |  |

Document Change Record

| Issue / Revision | Date | DCN. No | Changed Pages / Paragraphs |
| --- | --- | --- | --- |
| v1A | 25/11/2014 |  | Added ‘inflate=inflate’ after read\_rac in code.Added plots. |
| v1B | 14/07/2015 |  | Revised example IDL code, adding –PRIME to filename.  |
| v1C | 10/12/2015 |  | First published version.Revised text, following review by GSICS Product Acceptance Team.Updated example IDL code.Changed Document Signature Table & Reformatted. |

Table of Contents

1 Introduction 5

1.1 Purpose 5

1.2 Scope 6

1.3 Applicable Documents 6

1.4 Reference Documents 6

1.5 Document Structure 6

2 Preliminaries 7

3 Define Delta Correction 8

3.1 Define Delta Correction Uncertainty 8

3.2 Check Delta Correction Consistency 9

3.3 Check Delta Uncertainty Extrapolation 9

4 Apply Delta Correction to Secondary GSICS Corrections 11

4.1 Propagate Uncertainty to Modified Secondary Corrections 11

5 Blend GSICS Corrections from Individual References 13

Appendix A Example IDL Code 16

A.1 Main Program 17

A.2 calc\_delta 22

A.3 subset\_rac 23

A.4 hypirsno\_prime\_rac\_plot 24

Table of Figures

[Figure 1 – Schematic data flow diagram for generating Prime GSICS Correction, merging GSICS Corrections derived from multiple references, after applying Delta Corrections, based on their double differences, to transform them to the common scale of the Primary GSICS Reference. 5](#_Toc437599237)

[Figure 2 – Time Series of Radiance Biases (in K) calculated for Standard Radiance Scene from GSICS Re-Analysis Corrections for Meteosat-10/SEVIRI with respect to Metop-A/IASI (black) and Metop-B/IASI (red). 10](#_Toc437599238)

[Figure 3 – Time series of IASIA-IASIB double differences of biases above (black) with (grey) shading for k=1 uncertainty (inflated by a factor of 2), and equivalent biases calculated from cumulative Delta Correction (red), derived from same data over increasing time periods, with shading for k=1 (orange) k=2 (yellow) uncertainty limits. 10](#_Toc437599239)

[Figure 4 – Time Series of Radiance Biases (in K) calculated for Standard Radiance Scene from GSICS Re-Analysis Corrections for Meteosat-10/SEVIRI with respect to Metop-A/IASI (black) and Metop-B/IASI (red), Metop-B/IASI after delta correction (green), and Prime GSICS Re-Analysis Correction (blue), which obscures most other lines. 14](#_Toc437599240)

[Figure 5 – Time Series of k=1 uncertainties (in K) calculated for Standard Radiance Scene from GSICS Re-Analysis Corrections for Meteosat-10/SEVIRI with respect to Metop-A/IASI (black) and Metop-B/IASI (red), Metop-B/IASI after delta correction (green), the delta correction itself (cyan), and the Prime GSICS Re-Analysis Correction (blue), which obscures most other lines. 14](#_Toc437599241)

[Figure 6 – Time Series of relative weights of GSICS Corrections from primary reference (red) and secondary reference (green) used to calculate Prime Correction. 15](#_Toc437599242)

# Introduction

## Purpose

This document forms the Algorithm Theoretical Basis Document (ATBD) for the generation of *Prime GSICS Corrections*, by reading in GSICS corrections derived with different reference instruments, converting them to a common radiometric scale (that of the *Primary GSICS Reference*) and merging them to form one contiguous record. This ATBD is based on the Re-Analysis Corrections generated by EUMETSAT for the inter-calibration of Meteosat/SEVIRI images using IASI hyperspectral sounders on Metop-A and -B as reference instruments. This process is illustrated schematically in .

Reference

-

1

(Primary)

Monitored

Instrument

GSICS

Correction, g

1

Mon



1

Reference

-

2

(Secondary)

GSICS

Correction, g

2

Mon



2

Mon



1

Delta

Correction, g

1

/

2

2



1

**Derived by**

**GSICS**

**Applied**

**by User**

Modified

Correction, g

2

,

1

/

2

Mon



2



1

Prime

GSICS

Correction, g

0

Mon



1

**-**

<g>

**+**

Figure – Schematic data flow diagram for generating Prime GSICS Correction,
merging GSICS Corrections derived from multiple references,
after applying Delta Corrections, based on their double differences,
to transform them to the common scale of the Primary GSICS Reference.

## Scope

In future, further refinements will be needed to this ATBD to specifically include second (and third) order transfers for additional reference instruments which do not overlap with the primary reference instrument. In this case, an iterative series of double differences will be established, using secondary references to transfer the datum of the primary reference to any arbitrary period.

This ATBD covers the case of generating Prime GSICS Corrections for Re-Analysis applications. It can be modified by a simple extension to cover Near Real-Time applications.

## Applicable Documents

|  |  |  |
| --- | --- | --- |
| AD-1 | GSICS File Naming Convention, GSICS Development Wiki, 2015-07-06 | <https://gsics.nesdis.noaa.gov/wiki/Development/FilenameConvention> |
| AD-2 | GSICS Data Server Configuration, GSICS Development Wiki, 2015-04-29 | <https://gsics.nesdis.noaa.gov/wiki/Development/DataServerConf> |
| AD-3 | GSICS netCDF Convention, GSICS Development Wiki, 2015-07-31 | <https://gsics.nesdis.noaa.gov/wiki/Development/NetcdfConvention> |

## Reference Documents

|  |  |  |
| --- | --- | --- |
| GSICS Correction ATBD | “ATBD for EUMETSAT Pre-Operational GSICS Inter-Calibration of Meteosat-IASI” | EUM/MET/TEN/11/0268[Available online](http://www.eumetsat.int/website/wcm/idc/idcplg?IdcService=GET_FILE&dDocName=PDF_GSICS_MSG_P-OP_ATBD&RevisionSelectionMethod=LatestReleased&Rendition=Web) |
| Hewison, 2013 | “An Evaluation of the Uncertainty of the GSICS SEVIRI-IASI Inter-Calibration Products" | IEEE Transactions on Geoscience Remote Sensing, Vol. 51, no. 3, Mar. 2013, doi: [10.1109/TGRS.2012.2236330](http://dx.doi.org/10.1109/TGRS.2012.2236330). |

##

## Document Structure

This document is structured in sections following the logical steps of the ATBD as follows:

# Preliminaries

The initial step is to define the *Monitored Satellite/Instrument* and the *Reference Satellite(s)/Instrument(s)*, the type of inter-calibration product – i.e. *Near Real-Time Correction* (NRTC) or *Re-Analysis Correction* (RAC), and distribution mode of the product – i.e. *Demonstration*, *Pre-operational, Operational*. These in turn define the paths and names of the files which are required as inputs and output from the process of generating the Prime GSICS Correction, according to the conventions adopted in the configuration of the GSICS Data and Products Server [[GSICS Wiki](https://gsics.nesdis.noaa.gov/wiki/Development/DataServerConf)].

The input data are then read from the input files, following the GSICS netCDF convention defined on the [[GSICS Wiki](https://gsics.nesdis.noaa.gov/wiki/Development/NetcdfConvention)].

The following terminology is used in this ATBD:

GSICS Correction to Reference1   Equation

GSICS Correction to Reference2   Equation

where

*LMON*is the radiance of the Monitored instrument in channel *j* ,

*LREF1*is the radiance of Reference instrument 1, spectrally matching channel *j* ,

*LREF2*is the radiance of Reference instrument 2, spectrally matching channel *j* ,

**g1** is the GSICS Correction to convert Reference 1 to the monitored instrument,

**g2** is the GSICS Correction to convert Reference 2 to the monitored instrument,

*a*1 and *b*1 are offset and slope coefficients of a linear function describing **g1**,

*a*2 and *b*2 are offset and slope coefficients of a linear function describing **g**2.

 (Channel subscripts *j* are omitted here for clarity.)

The coefficients *a* and *b* are read from the current netCDF variables *offset* and *slope*, respectively. These have (*i*, *j*) dimensions of (date, channel) in the case of the Re-Analysis Correction.

The uncertainties on the coefficients, *u*(*a*) and *u*(*b*) are also read from variables, *offset\_se* and *slope\_se*, and their covariance *u*(*a*, *b*) is read from the variable *covariance.* These uncertainties are inflated by a factor of 2 upon reading, following the recommendations of [[Hewison, 2013](http://dx.doi.org/10.1109/TGRS.2012.2236330)].

n.b. It has been proposed to deprecate these variable names in the future and replace them with the generic names for the coefficients and their covariance. This ATBD will be revised accordingly if needed.

# Define Delta Correction

The *Delta Correction* is used to convert GSICS Corrections derived with one reference instrument to be metrologically consistent with those derived from another reference instrument, for the same monitored instrument.

The *Delta Correction* is derived from the double difference between pairs of GSICS Corrections derived from different reference instruments. It is defined by all available coincident data derived from the beginning of the overlap period, when data from both reference instruments were first available simultaneously, until the date for which the *Prime GSICS Correction* is to be defined. In this way, the delta corrections are expected to improve with time, as the overlap period grows and the uncertainty on the delta correction will tend to decrease.

This ensures the *Prime GSICS Correction* is directly traceable to the *Primary GSICS Reference* for this spectral band – denoted here as *REF1*.

A threshold of a minimum number of 7 days is applied to prevent erratic results during the initial overlap period. This threshold may be revised for specific instruments.

Combining equations (1) and (2), allows us to define the *Delta Correction* from *REF2* to *REF1*, **g1/2** as:

 **Equation 3**

where denotes the GSICS Correction with respect to REF1, defined at time step, *i*,

and <...> denotes the average of these time series.

In the simple case where the GSICS Correction is a linear function of the reference radiance, defined by an offset term, *a*, and a slope term, *b*, we can write (3) as:

 **Equation 4**

## Define Delta Correction Uncertainty

The uncertainty of the delta correction can be estimated as the standard error of the same time series used to define it, after accounting for over-sampling introduced by smoothing process introduced by applying a rolling window to the collocation data used to define its component GSICS Corrections.

The simplest way to express this uncertainty is in matrix notation, starting with the matrix of the residuals of the delta correction, **e1/2**:

** Equation 5**

The covariance of these residuals is then evaluated as **E1/2:**

** Equation 6**

This covariance needs to be corrected to account for the oversampling factor, :

** Equation 7**

where *P* = Smoothing Period, *n* = number of samples, and Δ*t* = Overlap Period.

The delta correction uncertainty, , is then estimated from the covariance matrix, **E1/2**, as:

** Equation 8**

## Check Delta Correction Consistency

However, tests on the Delta Correction are necessary to ensure:

1. There are no step changes in the relative difference between the reference instruments,
2. There is no significant trend in their difference,
3. There are no significant periodic oscillations in their difference.

At present these tests are implemented offline on an ad hoc basis. This part of the ATBD will be developed fully for pre-operational status, based on section 5 of the ATBD describing the generation of the individual GSICS Corrections [[ATBD](http://www.eumetsat.int/website/wcm/idc/idcplg?IdcService=GET_FILE&dDocName=PDF_GSICS_MSG_P-OP_ATBD&RevisionSelectionMethod=LatestReleased&Rendition=Web)], from which these Prime GSICS Corrections are derived.

For now, it is assumed that there are no significant step changes, trends or oscillations in the time series of the double difference coefficients. So, we can use all the collocations obtained over the entire overlap period when both secondary and primary references are available to define the *delta corrections*.

## Check Delta Uncertainty Extrapolation

If significant trends or oscillations are found above, the delta correction’s uncertainty should be inflated when it is extrapolated to apply to periods beyond the overlap period when both references are available. As no significant trend or oscillation has been detected in the case of the inter-calibration of SEVIRI with Metop-A/IASI and Metop-B/IASI, it has not been necessary to fully define the methodology for this extrapolation. This step will be defined in future as needed.

Figure 2 shows the biases calculated from the GSICS Corrections from the two references (Metop-A/IASI and Metop-B/IASI), which are almost indistinguishable on this scale for most of the time series (except for occasional jumps in IR6.3 using IASI-B). Figure 3 shows the time series of their double difference, and the delta correction defined cumulatively from it using Equation 4 (after converting to equivalent brightness temperature bias for a standard radiance scene), together with their associated uncertainties. This shows that step changes in either time series increase the uncertainty in the delta correction.



Figure – Time Series of Radiance Biases (in K) calculated for Standard Radiance Scene from GSICS Re-Analysis Corrections for Meteosat-10/SEVIRI with respect to Metop-A/IASI (black) and Metop-B/IASI (red).



Figure – Time series of IASIA-IASIB double differences of biases above (black) with (grey) shading for k=1 uncertainty (inflated by a factor of 2), and equivalent biases calculated from cumulative Delta Correction (red), derived from same data over increasing time periods, with shading for k=1 (orange) k=2 (yellow) uncertainty limits.

# Apply Delta Correction to Secondary GSICS Corrections

Next, we need to apply the *delta corrections* **g1/2** to the coefficients of the GSICS Correction derived from secondary reference instrument, **g2**, to make them metrologically consistent with those derived from the primary reference, **g1**. This defines a modified GSICS Correction, **g2,1/2**:

 **Equation 9**

In the case of the simple linear form of the GSICS Correction, this can be written as:

 **Equation 10**

where the coefficients of **g2,1/2** are: 

## Propagate Uncertainty to Modified Secondary Corrections

To estimate the uncertainty on the coefficients of the modified secondary corrections, **g2,1/2**, we perform a normal error propagation on Equation 10, first by defining the partial derivatives of the coefficients:

Partial derivatives of :  **Equation 11**

Partial derivatives of :  **Equation 12**

For simplicity, we assume no correlation between Delta Correction and GSICS Corrections:

  **Equation 13**

These are then combined with the uncertainties on the coefficients, *u*(*a*1), *u*(*b*1), *u*(*a*2), *u*(*b*2):

 **Equation 14**

 **Equation 15**

Similarly, for simplicity, we make the crude approximation that the coefficients’ covariance is proportional to their fractional uncertainty, scaled by the covariance of the secondary correction coefficients:

 **Equation 16**

These equations can be written more concisely in matrix notation:

 **Equation 17**

 **Equation 18**

 **Equation 19**

 **Equation 20**

where **U1**, **U2**, **U1/2** and **U2,1/2** are the covariance matrices of the uncertainties on the coefficients of the GSICS Corrections derived with the primary, secondary, delta, and modified secondary corrections, respectively.

# Blend GSICS Corrections from Individual References

The *Prime GSICS Correction* is defined as a weighted average of the coefficients of the GSICS Corrections derived from all available individual reference instruments, after modifying them to be consistent with the primary reference.

The relative weightings are defined from the uncertainties from the individual references, if both are available. If only one is available for a given date, it alone will define the Prime GSICS Correction. Hence, the covariance, **U0**, of the weighted average for dates when multiple references are available is given by:

If **g1** and **g2,1/2** available: 

If only **g1** available:  **Equation 21**

If only **g2,1/2** available: 

(In the example code given in Appendix A, this switch is implemented by scaling **U1** and **U2,1/2** by factors of nj1 and nj3 respectively, which are either 0 or 1.)

The Prime GSICS Correction is then given by:

 **Equation 22**

This calculation can be performed iteratively, following the general form described below for the coefficients derived with the primary reference, **g1**, and secondary references, modified as described above, **g2,1/2**.

A new netCDF file is then created, for the prime GSICS Correction, following the GSICS file naming convention (GSICS 2013). The coefficients of prime GSICS Correction and their uncertainties are then written to this netCDF file and it is transferred to the upload directory of the appropriate GSICS Server as defined on the [[GSICS Wiki](https://gsics.nesdis.noaa.gov/wiki/Development/DataServerConf)].

Figure 4 shows the biases calculated from the Prime GSICS Correction for the whole period of this sample dataset. In this case, the GSICS Corrections from the two references (Metop-A/IASI and Metop-B/IASI) are almost indistinguishable on this scale, and the Prime GSICS Correction obscures the other lines, which it overplots, confirming its consistency.

Figure 5 shows the uncertainty in the radiance biases calculated from the GSICS Corrections derived from individual references, and compares these with the uncertainty on the delta correction, which increases the uncertainty on the GSICS Correction from the secondary reference when it is applied. In turn, this reduces its weight in the blended average that makes up the Prime GSICS Correction – so its uncertainty is only a little better than that of the GSICS Correction from the primary reference.



Figure – Time Series of Radiance Biases (in K) calculated for Standard Radiance Scene from GSICS Re-Analysis Corrections for Meteosat-10/SEVIRI with respect to Metop-A/IASI (black) and Metop-B/IASI (red), Metop-B/IASI after delta correction (green), and Prime GSICS Re-Analysis Correction (blue), which obscures most other lines.



Figure – Time Series of k=1 uncertainties (in K) calculated for Standard Radiance Scene from GSICS Re-Analysis Corrections for Meteosat-10/SEVIRI with respect to Metop-A/IASI (black) and Metop-B/IASI (red), Metop-B/IASI after delta correction (green), the delta correction itself (cyan), and the Prime GSICS Re-Analysis Correction (blue), which obscures most other lines.



Figure – Time Series of relative weights of GSICS Corrections from primary reference (red) and secondary reference (green) used to calculate Prime Correction.

Figure 6 shows how the relative weights of the constituent parts of the Prime GSICS Correction vary with time, depending on the relative uncertainty of the GSICS Corrections derived from primary and secondary references. Initially only the primary reference is available, so the Prime GSICS Correction is based purely on that. It continues to dominate the secondary reference for most of the remainder of the time series, due to the extra uncertainty introduced by applying the delta correction. However, there are some periods where the GSICS Correction from the secondary reference dominates – for example when an outage in the data feed to this demonstration product from Metop-A/IASI occurred in January 2014.

1. Example IDL Code

The example code in this appendix uses variable names which map to the symbols used in this ATBD as follows:

|  |  |  |
| --- | --- | --- |
| **Define GSICS Corrections and Uncertainties in Matrix notation** |  | **g1=[a1,b1]****g2=[a2,b2]****g12=[a12,b12]****g3=[a3,b3]****ug1=[[ua1^2,uab1],$** **[uab1,ab1^2]]****...** |
| **Weighted average of RAC1 and RAC2+Delta12****weighted by uncertainties** |  | **ug0=INVERT($** **INVERT(u1)+$** **INVERT(u3))****g0=ug0#INVERT(ug1)#$** **INVERT(ug3)#g3****ua0=SQRT(ug0[0,0])****ub0=SQRT(ug0[1,1])****uab0=ug0[0,1]** |
| **Standard Error of Delta Correction from Ref1 to Ref2** | **Matrix of Residuals:****Covariance of Residuals:****Over-sampling Factor:****Delta Correction Uncertainty (Covariance Matrix):** | **Matrix of Residuals:****Covariance of Residuals:****Over-sampling Factor:****Delta Correction Uncertainty (Covariance Matrix):** | **residualMatrix= [a12-MEAN(a12), b12-MEAN(b12)]****residualCovar=** **(residualMatrix)#** **TRANSPOSE (residualMatrix)/n** **osf=windowPeriod\*n****/(MAX(jd)-MIN(jd))****deltaCovar= residualCovar/** **n\*osf****ua12=sqrt($** **deltaCovar[0,0])****ub12=sqrt($** **deltaCovar[1,1])****uab12=$** **deltaCovar[0,1]** |
| **Apply Delta Correction to Ref2 GSICS Corrections** |  |  | **Lmon=a3+b3\*Lref1****a3=a2+b2\*ma12****b3=b2\*mb12** |

n.b. the coefficients *a*1/2 and *b*1/2 are written as a3 and b3, respectively.

* 1. Main Program

;----------------------------------------------------------------------------

;+

; FILE:

; hypirsno\_prime\_rac.pro

;

; PURPOSE:

; IDL procedure to calculate Prime GSICS Re-Analysis Correction (RAC)

; by reading in existing RAC files derived from multiple references (in netCDF)

; and output to new netCDF file for upload to GSICS Data and Prodcuts Server

;

; REFERENCE:

; None

;

; COMMON BLOCKS:

; none

;

; DEPENDENCIES: LOTS!!

; Coyote's IDL Library ;Available from http://www.idlcoyote.com/

; subset\_rac ;in /tcc1/home/timothyh/idl/

; calc\_delta ;in /tcc1/home/timothyh/satcal/hypirsno/

; hypirsno\_prime\_rac\_plot ;in /tcc1/home/timothyh/satcal/hypirsno/

;

; INPUTS:

; cmonp, cmoni ;Monitored platform, instrument

;Given: crefp, crefi ;Reference platform(s), instrument(s)

;

; OUTPUTS:

; result\_filename ;NetCDF file of output Prime GSICS Correction

;

; OPTIONS:

; Tb=Tb ;scene brightness temperature(s) (default = standard scene)

; inflate=inflate ;keyword to inflate uncertainties by a given factor

; plotvar=plotvar ;select which variables to plot (if any)

;

; VARIABLES:

; x1 Structure for coefficients of GSICS Correction with Primary Reference

; x2 Coefficients of GSICS Correction with Secondary Reference

; x3 Coefficients of GSICS Correction with Secondary Reference after Delta Correction

; n.b. x3 is an abbreviation of x{2,1/2} in the ATBD

; x4 RAC from Primary Ref, merged with Secondary Reference after Delta Correction

; x0 Coefficients of Prime GSICS Correction from all References merged cumulatively

;

; MODIFICATION HISTORY:

; Written by: Tim Hewison 2014-08-29 - Based on ~/satcal/msg-iasi/delta\_applied3.pro

; Initially just based on time series when Primary Reference is available

; Then code up first order transfers

; Eventually need to generalise to cover whole period when any reference available

;

; Comments refer to equation numbers in ATBD for Demo Prime GSICS Correction [EUM/RSP/TEN/14/777892]

;

; See revision\_history variable for full version history

;-

;----------------------------------------------------------------------------

pro hypirsno\_prime\_rac, cmonp, cmoni, result\_filename, Tb=Tb, crash=crash, inflate=inflate,daily=daily, preop=preop, clr=clr, plotvar=plotvar, before=before, after=after

revision\_history=[$

'v00.00.00 2014-09-03 initial prototype version',$

'v00.00.01 2014-09-04 date\_created now preserved from previous output file (if any)',$

'v00.00.02 2014-09-05 changed name from Primary RAC to Prime RAC',$

'v00.01.00 2014-09-05 added revision\_history global attribute',$

'v00.01.01 2014-09-05 file path removed from id global attribute',$

'v00.02.00 2014-11-25 fixed missing pass of inflate keyword to read\_rac',$

'v00.03.00 2015-07-14 added -PRIME to filename and replaced hhmmdd with ------',$

'v00.03.01 2015-09-01 forced \_FillValue attribute to match format of variable',$

'v00.03.02 2015-11-05 Reverted from ------ in the filename to 000000',$

'v00.04.00 2015-12-17 Updated netCDF content following GPAT review. fixed delta\_min\_days=1',$

'']

;Todo list:

;Change to netCDF4!

;Implement Delta Correction uncertainty growth when extrapolating after Ref1 dies

;

;Setup default configurations:

version=STRMID((reverse(revision\_history))[1],1,8) ;Use most recent version from list

pathStem=EXPAND\_PATH('$PROJ\_GSICS/results/')

type='RAC'

mode='demo'

processing\_level='demonstration'

IF KEYWORD\_SET(preop) THEN mode='preop'

IF KEYWORD\_SET(preop) THEN processing\_level='preoperational'

delta\_min\_days=1 ;2015-12-17 - was 7, but caused problems at start

delim=';'+STRING(10b) ;Delimiter for multiple strings in netCDF global attributes

;Define pecking order for references:

crefp=['metopa','metopb','metopc','snpp', 'jpss', 'aqua']

crefi=['iasi', 'iasi', 'iasi', 'cris', 'cris', 'airs']

IF ~KEYWORD\_SET(cmonp) THEN cmonp='msg3'

IF ~KEYWORD\_SET(cmoni) THEN cmoni='seviri'

PRINT,'Generating Prime GSICS RAC for ',cmonp,'/',cmoni,'...'

;Define inputs as pair of GSICS Corrections:

;(file1, x1) is for the Primary Reference, (file2, x2) is for the Secondary Reference

file1=FILE\_SEARCH(pathStem+'/'+cmoni+'/'+cmonp+'/'+crefi[0]+'/'+crefp[0]+'/\*'+type+'\*'+mode+'\*.nc')

read\_rac,file1[0],x1,inflate=inflate ;Read GSICS Correction for Primary Reference

nch=N\_ELEMENTS(x1.central\_wavelength) ;Preliminaries...

Lstd=msg\_tb2rad(x1.std\_scene\_tb) ;Standard radiance used to propagate uncertainty

;Filter time series if before and/or after attributes set:

IF KEYWORD\_SET(after) THEN $

 x1=subset\_rac(x1,WHERE(x1.jd GT ymd2jd(after)))

IF KEYWORD\_SET(before) THEN $

 x1=subset\_rac(x1,WHERE(x1.jd LT ymd2jd(before)))

;Initialise Prime GSICS Correction, based on GSICS Correction for Primary Reference:

x0=x1 ;Itteratively merged with RAC for each reference

file2=STRARR(N\_ELEMENTS(crefp)) ;All Secondary Corrections

iRefUsed=0 ;Create list of References Used

;Loop through all Secondary References: -

;(higher order transfers implemented iteratively after first order)

FOR k=1,N\_ELEMENTS(crefp)-1 DO BEGIN

 file2[k]=FILE\_SEARCH(pathStem+'/'+cmoni+'/'+cmonp+'/'+crefi[k]+'/'+crefp[k]+'/\*'+type+'\*'+mode+'\*.nc')

 IF (file2[k] NE '') THEN BEGIN ;Check whether RAC exists for each Secondary Reference

 iRefUsed=[iRefUsed,k] ;Record that we have used this reference

 read\_rac,file2[k],x2

 x3=x2 ;Secondary Correction after Delta Corrected

 jd4=setunion(x0.jd,x2.jd) ;Combine this reference with time series so far

 nj4=N\_ELEMENTS(jd4)

 arr=FLTARR(nch,nj4) ;dummy to define arrays

 arrwt=FLTARR(nch,N\_ELEMENTS(crefp),nj4)

 x4={offset:arr,offset\_se:arr,slope:arr,slope\_se:arr,covariance:arr,$

 std\_scene\_tb:FLTARR(nch),std\_scene\_tb\_bias:arr,std\_scene\_tb\_bias\_se:arr,jd:jd4,$

 number\_of\_collocations:arr,alert:BYTARR(nj4),validity\_period:DBLARR(2,nj4),$

 w0a:arr,w3a:arr,w0b:arr,w3b:arr,ref\_wt:arrwt} ;Weights for merging a & b

 FOR j4=0,nj4-1 DO BEGIN ;Loop though all dates with data

 ok0=WHERE(x0.jd LE jd4[j4],nok0) ;Identify period up to j4

 ok2=WHERE(x2.jd LE jd4[j4],nok2)

 j0=(WHERE(x0.jd EQ jd4[j4],nj0))[0] ;Identify first matching timestep

 j1=(WHERE(x1.jd EQ jd4[j4],nj1))[0] ;nj0,nj1,nj2,nj3 are either 0 or 1

 j2=(WHERE(x2.jd EQ jd4[j4],nj2))[0]

 j3=(WHERE(x3.jd EQ jd4[j4],nj3))[0] ;Same as j2 (after delta correction)

 IF nok0 GE delta\_min\_days AND nok2 GE delta\_min\_days THEN BEGIN ;Only if Ref1 and Ref2 correction present!

 a1=x0.offset[\*,j0] ;Copy coeffs to temporary vars

 ua1=x0.offset\_se[\*,j0];^2 ;lower-case u prefix = uncertainty

 b1=x0.slope[\*,j0]

 ub1=x0.slope\_se[\*,j0];^2

 uab1=x0.covariance[\*,j0] ;uab=covariance of a and b

 a2=x2.offset[\*,j2]

 ua2=x2.offset\_se[\*,j2];^2

 b2=x2.slope[\*,j2]

 ub2=x2.slope\_se[\*,j2];^2

 uab2=x2.covariance[\*,j2]

 delta=calc\_delta(subset\_rac(x0,ok0),subset\_rac(x2,ok2)) ;Calc Delta Correction for period to j

 a12=delta.coeff[\*,0]

 ua12=SQRT(delta.covar[\*,0,0])

 b12=delta.coeff[\*,1]

 ub12=SQRT(delta.covar[\*,1,1])

 uab12=delta.covar[\*,0,1]

 a3 = a2+b2\*a12 ;ATBD Eq(10) - n.b. a3=a2,1/2

 b3 = b2\*b12 ;ATBD Eq(10)

 ua3=SQRT(ua2^2+a12^2\*ub2^2+b2^2\*ua12^2+2\*a12\*uab2);ATBD Eq(14)

 ub3=SQRT(b12^2\*ub2^2+b2^2\*ub12^2) ;ATBD Eq(15)

 uab3=(ua3/ua2)\*(ub3/ub2)\*uab2 ;ATBD Eq(16) - Crude Approximation!

 x3.offset[\*,j3] =a3

 x3.slope[\*,j3] =b3

 x3.offset\_se[\*,j3] =ua3

 x3.slope\_se[\*,j3] =ub3

 x3.covariance[\*,j3]=uab3

 ENDIF

 nj0=nj0\*(nok0 GE delta\_min\_days) ;If count<min then ignore

 nj3=nj3\*(nok2 GE delta\_min\_days)

;Calculate x4 as weighted average of x0 and x3, using matrix notation:

;Upper-case U = covariance of uncertainties

 FOR i=0,nch-1 DO BEGIN

 g0=[x0.offset[i,j0],x0.slope[i,j0]]

 U0=[[x0.offset\_se[i,j0]^2,x0.covariance[i,j0]],$

 [x0.covariance[i,j0],x0.slope\_se[i,j0]^2]]

 g3=[x3.offset[i,j3],x3.slope[i,j3]]

 U3=[[x3.offset\_se[i,j3]^2,x3.covariance[i,j3]],$

 [x3.covariance[i,j3],x3.slope\_se[i,j3]^2]]

 U4=INVERT(nj0\*INVERT(U0)+nj3\*INVERT(U3)) ;ATBD Eq(21)

 g4=U4#(nj0\*INVERT(U0)#g0+nj3\*INVERT(U3)#g3) ;ATBD Eq(22)

 x4.offset\_se[i,j4]=SQRT(U4[0,0])

 x4.slope\_se[i,j4] =SQRT(U4[1,1])

 x4.covariance[i,j4]=U4[0,1]

 x4.offset[i,j4]=g4[0]

 x4.slope[i,j4]=g4[1]

 x4.w0a[i,j4]=(nj0\*INVERT(U0)/INVERT(U4))[0,0] ;Store weights

 x4.w0b[i,j4]=(nj0\*INVERT(U0)/INVERT(U4))[1,1] ;Store weights

 x4.w3a[i,j4]=(nj3\*INVERT(U3)/INVERT(U4))[0,0] ;Store weights

 x4.w3b[i,j4]=(nj3\*INVERT(U3)/INVERT(U4))[1,1] ;Store weights

 x4.ref\_wt[i,k,j4]=MEAN([x4.w3a[i,j4],x4.w3b[i,j4]]) ;Store mean weight

 x4.number\_of\_collocations[i,j4]=nj0\*x0.number\_of\_collocations[i,j0]+nj3\*x3.number\_of\_collocations[i,j3]

 ENDFOR ;i:channel

 x4.alert[j4]=x0.alert[j0]-x1.alert[j1]+x3.alert[j3]

 x4.validity\_period[0,j4]=MIN([x0.validity\_period[0,j0],x3.validity\_period[0,j3]])

 x4.validity\_period[1,j4]=MAX([x0.validity\_period[1,j0],x3.validity\_period[1,j3]])

 x4.std\_scene\_tb=x3.std\_scene\_tb

 ENDFOR ;j4:date

 ENDIF ;file2 exists

 x0=x4 ;Updated Prime GSICS Correction with merged RACs

ENDFOR ;k:reference

x0.ref\_wt[\*,0,\*]=1.-TOTAL(x4.ref\_wt[\*,1:\*,\*],2) ;Calc Primary Reference weight

;Now go through all channels and evaluate time series of standard biases from Primary RAC:

FOR i=0,nch-1 DO BEGIN

 Tbstd=x0[0].std\_scene\_tb[i]

 Rad=(msg\_tb2rad(Tbstd,ich=i+1))[0]

 dRad=TRANSPOSE(x0.offset[i,\*]+(x0.slope[i,\*]-1)\*Rad)

 sdRad=TRANSPOSE(SQRT(x0.offset\_se[i,\*]^2+x0.slope\_se[i,\*]^2\*Rad^2+2\*x0.covariance[i,\*]\*Rad))

 dTb=REFORM(msg\_rad2tb(Rad+dRad,ich=i+1)-Tbstd)

 x0.std\_scene\_tb\_bias[i,\*]=dTb

 x0.std\_scene\_tb\_bias\_se[i,\*]=REFORM(msg\_rad2tb(Rad+dRad+sdRad,ich=i+1)-Tbstd-dTb)

ENDFOR ;i (channel)

;Generate optional plots:

IF KEYWORD\_SET(plotvar) THEN hypirsno\_prime\_rac\_plot,x0,x1,x2,x3,delta,Tb=Tb,plotvar=plotvar

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;Output results to Prime GSICS RAC netCDF file:

;Makes extensive use of netCDF methods from Coyote's IDL library

;Create tag in output structure for date (seconds since 1970):

x0=CREATE\_STRUCT(x0,'date',(x0.jd-JULDAY(01,01,1970,00,00,00))\*86400.)

startdate=jd2ymd(MIN(x0.jd),/hms)

;startdate=jd2ymd(MIN(x0.jd))+'------' ;Reverted 2015-11-05

;Create filename to store Prime RAC in netCDF format:

file0=pathStem+'/'+cmoni+'/'+cmonp+'/prime/W\_XX-EUMETSAT-Darmstadt,SATCAL+RAC+GEOLEOIR,'+$

 STRUPCASE(cmonp+'+'+cmoni)+'-PRIME\_C\_EUMG\_'+startdate+'\_'+mode+'\_'+STRMID(version,0,2)+'.nc'

file1=file1;!

;First check whether output file already exists - if so, extract date\_created attribute:

IF FILE\_SEARCH(file0) THEN BEGIN &$

 read\_ncdf,file0,xold,/att &$

 date\_created=xold.date\_created &$

ENDIF ELSE BEGIN &$

 date\_created=jd2iso8601(SYSTIME(/JULIAN,/UTC),/hms) &$

ENDELSE

; Open the source file in read-only mode.

;sObj = Obj\_New('NCDF\_FILE', file1, ErrorLoggerName='sourcefilelogger', /TIMESTAMP)

sObj = Obj\_New('NCDF\_FILE', file1, /TIMESTAMP)

IF Obj\_Valid(sObj) EQ 0 THEN Message, 'Source object cannot be created:'+file1

;IF Obj\_Valid(sObj) EQ 0 THEN STOP, 'Source object cannot be created:'+file1

; Open the destination file for writing.

dObj = Obj\_New('NCDF\_FILE', file0, /CREATE, /CLOBBER, ErrorLoggerName='destinationfilelogger', /TIMESTAMP)

IF Obj\_Valid(dObj) EQ 0 THEN Message, 'Destination object cannot be created:'+file0

; Find all the global attributes in the source file and copy them:

attrNames = sObj -> GetGlobalAttrNames(COUNT=attrCount)

FOR j=0,attrCount-1 DO sObj -> CopyGlobalAttrTo, attrNames[j], dObj

; Find all the dimensions in the source file and copy them:

dimNames = sObj -> GetDimNames(COUNT=dimCount)

FOR j=0,dimCount-1 DO sObj -> CopyDimTo, dimNames[j], dObj

; Find all variable definitions, attributes and data in source file and copy them:

varNames = sObj -> GetVarNames(COUNT=varCount)

FOR j=0,varCount-1 DO BEGIN &$

 sObj -> CopyVarDefTo, varNames[j], dObj &$

 varAttrNames = sObj -> GetVarAttrNames(varNames[j], COUNT=varAttrCount) &$

 varType = TYPENAME(sObj -> GetVarData(varNames[j])) &$

 FOR k=0,varAttrCount-1 DO BEGIN &$

;2015-09-01 Following clause inserted to fix bug with FillValue

 IF (varAttrNames[k] EQ '\_FillValue') THEN BEGIN

 attrValue = sObj -> GetVarAttrValue(varNames[j],varAttrNames[k],DATATYPE=attrType)

 dObj -> WriteVarAttr,varNames[j],varAttrNames[k],attrValue,DATATYPE=varType

 ENDIF ELSE BEGIN

 sObj -> CopyVarAttrTo, varNames[j], varAttrNames[k], dObj &$

 ENDELSE

 ENDFOR &$

 sObj -> CopyVarDataTo, varNames[j], dObj &$

ENDFOR

;Make changes to the content of the Primary GSICS RAC:

dObj->WriteGlobalAttr,'title',STRUPCASE(cmonp+'+'+cmoni)+' Prime GSICS Re-Analysis Correction'

dObj->WriteGlobalAttr,'date\_created',date\_created

dObj->WriteGlobalAttr,'date\_modified',jd2iso8601(SYSTIME(/JULIAN,/UTC),/hms)

dObj->WriteGlobalAttr,'history',jd2iso8601(SYSTIME(/JULIAN,/UTC),/hms)+' hypirsno\_prime\_rac, '+$

 'inflate='+STRING(KEYWORD\_SET(inflate)?inflate:1)+delim+$

 'Primary Reference RAC File: '+file1+delim+$

 'Secondary Reference(s) RAC File(s): '+STRJOIN([file2[1:\*]+delim])

dObj->WriteGlobalAttr,'processing\_level',processing\_level+'/v'+version

dObj->WriteGlobalAttr,'time\_coverage\_start',jd2iso8601(MIN(x0.jd),/hms)

dObj->WriteGlobalAttr,'time\_coverage\_end',jd2iso8601(MAX(x0.jd),/hms)

dObj->WriteGlobalAttr,'id',(REVERSE(STRSPLIT(file0,'/',/EXTRACT)))[0]

IF (type EQ 'RAC') THEN dObj->WriteGlobalAttr,'window\_period','P-14D+14D' ;v00.04.00

IF (type EQ 'NRTC') THEN dObj->WriteGlobalAttr,'window\_period','P-14D+0D' ;v00.04.00

dObj->WriteGlobalAttr,'comment','These Prime GSICS Re-Analysis Corrections allow the data from the infrared channels'+$

' of this Meteosat SEVIRI to be corrected to be radiometrically consistent with the Primary GSICS Reference (MetopA/IASI).'+$

' This is achieved by combining inter-calibration results using different IASIs, as secondary references. '+delim+$

'Use the RAC with the time closest to the time of interest.'+$

' Take great caution when applying it to a date where this difference is greater than the window\_period'

;IF ~dObj->HasGlobalAttr('revision\_history') THEN $

dObj->WriteGlobalAttr,'revision\_history',STRJOIN([revision\_history+delim]),DATATYPE='CHAR'

dObj->WriteDim,'date',N\_ELEMENTS(x0.jd),/unlimited

;v04.00.00

refNames=STRUPCASE(crefp[iRefUsed]+'+'+crefi[iRefUsed])

dObj->WriteDim,'ref',[N\_ELEMENTS(refNames)], OBJECT=refObj

dObj->WriteDim,'ref\_strlen',[MAX(STRLEN(crefp+'+'+crefi))], OBJECT=ref\_strlenObj

dimNames=[refObj->GetName(), ref\_strlenObj->GetName()]

dObj->WriteVarDef,'reference\_name', dimNames, DATATYPE='CHAR';, OBJECT=varObj

dObj->WriteVarData,'reference\_name',refNames

dObj->WriteVarData,'number\_of\_collocations',x0.number\_of\_collocations

dObj->WriteVarData,'offset',x0.offset

dObj->WriteVarData,'offset\_se',x0.offset\_se

dObj->WriteVarData,'slope',x0.slope

dObj->WriteVarData,'slope\_se',x0.slope\_se

dObj->WriteVarData,'covariance',x0.covariance

dObj->WriteVarData,'std\_scene\_tb\_bias',x0.std\_scene\_tb\_bias

dObj->WriteVarData,'std\_scene\_tb\_bias\_se',x0.std\_scene\_tb\_bias\_se

dObj->WriteVarData,'date',x0.date

dObj->WriteVarData,'alert',x0.alert

dObj->WriteVarData,'validity\_period',x0.validity\_period

dObj->WriteVarDef,'reference\_weight',['chan','ref','date'],$

 DATATYPE='FLOAT',OBJECT=wtObj,/take\_first ;v00.04.00 - /take\_first keyword workaround for bug?

dObj->WriteVarData,wtObj,x0.ref\_wt[\*,iRefUsed,\*] ;v00.04.00

; Sync the destination file.

dObj->Sync

PRINT,'Written Prime GSICS RAC to ',file0,'.'

IF KEYWORD\_SET(crash) THEN STOP

; Destroy both the source and destination objects.

Obj\_Destroy,dObj

Obj\_Destroy,sObj

result\_filename=file0

RETURN

END

* 1. calc\_delta

FUNCTION calc\_delta, x1, x2, crash=crash

;IDL Fucntion to calculate Delta Correction from from double-differences

;of two given time series of RACs, x1 and x2

;Returns structure with coefficients and covariance of Delta Correction: delta.coeff, delta.covar

;

;2014-07-10 Written by Tim Hewison

;

jd1=JULDAY(01,01,1970,00,00,00)+x1.date/86400.

jd2=JULDAY(01,01,1970,00,00,00)+x2.date/86400.

nch=N\_ELEMENTS(x1.central\_wavelength)

;First common dates in both RAC time series:

both=setintersection(jd1,jd2)

ok1=0

ok2=0

FOR i=0,N\_ELEMENTS(both)-1 DO BEGIN

 o1=WHERE(jd1 eq both[i],no1)

 o2=WHERE(jd2 eq both[i],no2)

 IF no1 THEN ok1=[ok1,o1]

 IF no2 THEN ok2=[ok2,o2]

ENDFOR

IF N\_ELEMENTS(ok1) GT 1 THEN ok1=ok1[1:\*] ELSE RETURN,0 ;'No Overlap between x1 and x2!'

IF N\_ELEMENTS(ok2) GT 1 THEN ok2=ok2[1:\*] ELSE RETURN,0 ;'No Overlap between x1 and x2!'

nok1=N\_ELEMENTS(ok1)

nok2=N\_ELEMENTS(ok2)

deltaCoeff=FLTARR(nch,2)

deltaCovar=FLTARR(nch,2,2)

;Then extract offset and slope terms, calculate mean and covariance of their time series:

FOR i=0,nch-1 DO BEGIN

 a1=x1.offset[i,ok1]

 a2=x2.offset[i,ok2]

 b1=x1.slope[i,ok1]

 b2=x2.slope[i,ok2]

 a12=(a1-a2)/b2 ;ATBD Eq(4)

 b12=b1/b2 ;ATBD Eq(4)

 deltaCoeff[i,\*]=[MEAN(a12),MEAN(b12)]

 residualMatrix=[a12-MEAN(a12),b12-MEAN(b12)] ;ATBD Eq(5)

 residualCovar=TRANSPOSE(residualMatrix)##residualMatrix/nok1 ;ATBD Eq(6)

 windowPeriod=MEDIAN(x1.validity\_period[1,\*]-x1.validity\_period[0,\*])/86400.

 osf=windowPeriod\*nok2/(MAX(jd2[ok2])-MIN(jd2[ok2])) ;Oversampling Factor - ATBD Eq(7)

 deltaCovar[i,\*,\*]=residualCovar/nok2\*osf ;ATBD Eq(8)

ENDFOR

IF KEYWORD\_SET(crash) THEN STOP

RETURN, {coeff:deltaCoeff, covar:deltaCovar}

END

* 1. subset\_rac

FUNCTION subset\_rac, x, ok

;IDL function to subset the coefficients of the GSICS Correction in a strucutre, x,

;resulting from having having read it from the netCDF file using read\_ncdf

;Initiate new structure starting with tag date, subset by indices 'ok':

iDate=WHERE(TAG\_NAMES(x) EQ 'DATE') ;Index of DATE tag

nDate=N\_ELEMENTS(x.(iDate)) ;Number of dates

IF (iDate EQ 0) THEN BEGIN

 y={date:(x.(iDate))[ok]} ;Copy DATE into new structure

ENDIF ELSE BEGIN

 cTag=(TAG\_NAMES(x))[0] ;Extract this tag name

 y=CREATE\_STRUCT(cTag,(x.(0))) ;Just copy content if no date dimension

 IF (WHERE(SIZE(x.(0)) EQ nDate))[0] NE -1 THEN$

 STOP,'Oh dear! Frist tag has dimension DATE!'

ENDELSE

FOR i=1,N\_TAGS(x)-1 DO BEGIN

 cTag=(TAG\_NAMES(x))[i] ;Extract this tag name

 FindDate=(WHERE(SIZE(x.(i)) EQ nDate))[0] ;Look for dimension matching DATE

 CASE FindDate OF

 -1: y=CREATE\_STRUCT(y,cTag,(x.(i))) ;Just copy content if no date dimension

 1: CASE (SIZE(x.(i)))[0] OF ;How many dimensions is this tag?

 1: y=CREATE\_STRUCT(y,cTag,(x.(i))[ok]) ;Copy subset content

 2: y=CREATE\_STRUCT(y,cTag,(x.(i))[ok,\*])

 3: y=CREATE\_STRUCT(y,cTag,(x.(i))[ok,\*,\*])

 4: y=CREATE\_STRUCT(y,cTag,(x.(i))[ok,\*,\*,\*])

 ENDCASE ;SIZE(x.(i))

 2: CASE (SIZE(x.(i)))[0] OF ;How many dimensions is this tag?

 2: y=CREATE\_STRUCT(y,cTag,(x.(i))[\*,ok])

 3: y=CREATE\_STRUCT(y,cTag,(x.(i))[\*,ok,\*])

 4: y=CREATE\_STRUCT(y,cTag,(x.(i))[\*,ok,\*,\*])

 ENDCASE ;SIZE(x.(i))

 3: CASE (SIZE(x.(i)))[0] OF ;How many dimensions is this tag?

 3: y=CREATE\_STRUCT(y,cTag,(x.(i))[\*,\*,ok])

 4: y=CREATE\_STRUCT(y,cTag,(x.(i))[\*,\*,ok,\*])

 ENDCASE ;SIZE(x.(i))

 4: CASE (SIZE(x.(i)))[0] OF ;How many dimensions is this tag?

 4: y=CREATE\_STRUCT(y,cTag,(x.(i))[\*,\*,\*,ok])

 ENDCASE ;SIZE(x.(i))

 ENDCASE ;FindDate

ENDFOR ;i

RETURN,y

END

* 1. hypirsno\_prime\_rac\_plot

;----------------------------------------------------------------------------

;+

; FILE:

; hypirsno\_prime\_rac\_plot.pro

;

; PURPOSE:

; IDL procedure to plot Primary GSICS Re-Analysis Correction (RAC)

; calculated by hypirsno\_prime\_rac

;

; REFERENCE:

; None

;

; COMMON BLOCKS:

; none

;

; DEPENDENCIES:

; msg\_rad2tb ;in /tcc1/home/timothyh/idl/

; msg\_tb2rad ;in /tcc1/home/timothyh/idl/

;

; INPUTS:

; x1 Structure for coefficients of GSICS Correction with Primary Reference

; x2 Coefficients of GSICS Correction with Secondary Reference

; x3 Coefficients of GSICS Correction with Secondary Reference after Delta Correction

; n.b. x3 is an abbreviation of x{2,1/2} in the ATBD

; x4 RAC from Primary Ref, merged with Secondary Reference after Delta Correction

; x0 Coefficients of Prime GSICS Correction from all References merged cumulatively

;

; OUTPUTS:

; delta ;NetCDF file of output Prime GSICS Correction

;

; OPTIONS:

; Tb=Tb ;scene brightness temperature(s) (default = standard scene)

; plotvar ;Select what to plot:

; delta=biases from delta correction,

; dTb=biases, dTba=all biases

; dd=double differences of Tb biases,

; ddelta=dd+delta

; unc=uncertainties,

; wt=weights,

; offset(\_se), slope(\_se), covar,

; ncol

;

; MODIFICATION HISTORY:

; Written by: Tim Hewison 2014-09-03 - Based on ~/satcal/msg-iasi/delta\_applied3.pro

; Modified by Tim Hewison 2014-11-25 - to include more plot options

; Modified by Tim Hewison 2015-07-23 - changed date matching for 'dd' to account for gaps

;----------------------------------------------------------------------------

pro hypirsno\_prime\_rac\_plot, x0, x1, x2, x3, delta, Tb=Tb, crash=crash, plotvar=plotvar

if (n\_elements(tb) eq 8) then x1[0].std\_scene\_tb=tb ;Override standard

if (n\_elements(tb) eq 8) then x2[0].std\_scene\_tb=tb ;Override standard

nch=N\_ELEMENTS(x1.offset[\*,0])

chname=STRCOMPRESS(STRING(x1.central\_wavelength\*1e6,FORMAT='("IR",f4.1)'),/REMOVE\_ALL)

!p.multi=[0,2,4]

date\_label = LABEL\_DATE(DATE\_FORMAT=['%N','%Y'],/ROUND\_UP)

!X.TICKFORMAT = ['LABEL\_DATE', 'LABEL\_DATE']

!X.TICKUNITS = ['Month','Year']

!X.TICKINTERVAL = 1

!X.MINOR=1;4 ;30

!X.TICKLAYOUT = 2

!X.STYLE=1

!P.CHARSIZE=2;4 ;Settings for maximised plotting window

!P.THICK=2

ymax=KEYWORD\_SET(tb)?3.0:1.0

FOR i=0,nch-1 DO BEGIN

 Tb0=N\_ELEMENTS(tb)?tb:x1[0].std\_scene\_tb[i]

 Rad=(msg\_tb2rad(Tb0,ich=i+1))[0]

 dRad0=TRANSPOSE(x0.offset[i,\*]+(x0.slope[i,\*]-1)\*Rad)

 dRad1=TRANSPOSE(x1.offset[i,\*]+(x1.slope[i,\*]-1)\*Rad)

 dRad2=TRANSPOSE(x2.offset[i,\*]+(x2.slope[i,\*]-1)\*Rad)

 dRad3=TRANSPOSE(x3.offset[i,\*]+(x3.slope[i,\*]-1)\*Rad)

 sdRad0=TRANSPOSE(sqrt(x0.offset\_se[i,\*]^2+x0.slope\_se[i,\*]^2\*Rad^2+2\*x0.covariance[i,\*]\*Rad))

 sdRad1=TRANSPOSE(sqrt(x1.offset\_se[i,\*]^2+x1.slope\_se[i,\*]^2\*Rad^2+2\*x1.covariance[i,\*]\*Rad))

 sdRad2=TRANSPOSE(sqrt(x2.offset\_se[i,\*]^2+x2.slope\_se[i,\*]^2\*Rad^2+2\*x2.covariance[i,\*]\*Rad))

 sdRad3=TRANSPOSE(sqrt(x3.offset\_se[i,\*]^2+x3.slope\_se[i,\*]^2\*Rad^2+2\*x3.covariance[i,\*]\*Rad))

 dTb0=REFORM(msg\_rad2tb(Rad+dRad0,ich=i+1)-Tb0)

 dTb1=REFORM(msg\_rad2tb(Rad+dRad1,ich=i+1)-Tb0)

 dTb2=REFORM(msg\_rad2tb(Rad+dRad2,ich=i+1)-Tb0)

 dTb3=REFORM(msg\_rad2tb(Rad+dRad3,ich=i+1)-Tb0)

 sdTb0=REFORM(msg\_rad2tb(Rad+dRad0+sdRad0,ich=i+1)-Tb0-dTb0)

 sdTb1=REFORM(msg\_rad2tb(Rad+dRad1+sdRad1,ich=i+1)-Tb0-dTb1)

 sdTb2=REFORM(msg\_rad2tb(Rad+dRad2+sdRad2,ich=i+1)-Tb0-dTb2)

 sdTb3=REFORM(msg\_rad2tb(Rad+dRad3+sdRad3,ich=i+1)-Tb0-dTb3)

 !P.TITLE=x1.monitored\_instrument+' '+chname[i]

 !Y.TITLE=plotvar

 IF plotvar eq 'unc' THEN BEGIN

 PLOT,x1.jd,sdtb1,YTITLE='Uncertainty [K]'

 OPLOT,x2.jd,sdtb2,COLOR=2

 OPLOT,x3.jd,sdtb3,COLOR=3

 OPLOT,x3.jd,sdtb3-sdtb2,COLOR=5

 OPLOT,x0.jd,sdtb0,COLOR=4

 ENDIF

 IF STRMID(plotvar,0,3) EQ 'dTb' THEN BEGIN

 PLOT,x0.jd,dTb0,YTITLE='Tb Bias [K]',/NODATA,$

 YRANGE=[-1,+1]\*ymax\*(1+(i EQ 7))-(i EQ 7)

 OPLOT,x1.jd,dTb1;,PSYM=-1

 OPLOT,x2.jd,dTb2,COLOR=2;,PSYM=-4

 OPLOT,x0.jd,dTb0\*0.,LINESTYLE=2

 END

 IF plotvar EQ 'dTba' THEN BEGIN

 OPLOT,x3.jd,dTb3,COLOR=3;,PSYM=-2

 OPLOT,x0.jd,dTb0,COLOR=4;,PSYM=-2

 OPLOT,x0.jd,dTb0\*0.,LINESTYLE=2

 END

 IF STRMID(plotvar,0,2) EQ 'dd' THEN BEGIN

 MATCH,x1.jd,x2.jd,ok1,ok2 ;NASA GSFC AstroLib

 mdd=dTb1[ok1]-dTb2[ok2]

 sdd=SQRT((sdTb1[ok1]^2-sdTb2[ok2]^2)>0) ;Catch NANs->0

 dmax=max([1.0\*abs([mdd+sdd\*2,mdd-sdd\*2]),0.2\*ymax]) ;Re-scale if needed

 PLOT,x2.jd[ok2],mdd,YTITLE='Double Difference [K]',YRANGE=[-1,+1]\*dmax

 POLYFILL,[x2.jd[ok2],REVERSE(x2.jd[ok2])],[mdd+2\*sdd,REVERSE(mdd-2\*sdd)],color=15

 POLYFILL,[x2.jd[ok2],REVERSE(x2.jd[ok2])],[mdd+sdd,REVERSE(mdd-sdd)],color=14

 OPLOT,x2.jd[ok2],mdd

 OPLOT,x2.jd[ok2],dTb2[ok2]\*0.,LINESTYLE=2

 END

 IF plotvar EQ 'dddelta' THEN BEGIN

 mdd=dTb3-dTb2

 sdd=SQRT((sdTb3^2-sdTb2^2)>0) ;Catch NANs->0

 POLYFILL,[x3.jd,REVERSE(x3.jd)],[mdd+2\*sdd,REVERSE(mdd-2\*sdd)],color=7

 POLYFILL,[x3.jd,REVERSE(x3.jd)],[mdd+sdd,REVERSE(mdd-sdd)],color=8

 OPLOT,x3.jd,mdd,COLOR=2

 mdd=dTb1[ok1]-dTb2[ok2]

 sdd=SQRT((sdTb1[ok1]^2-sdTb2[ok2]^2)>0) ;Catch NANs->0

 POLYFILL,[x2.jd[ok2],REVERSE(x2.jd[ok2])],[mdd+2\*sdd,REVERSE(mdd-2\*sdd)],color=15

 POLYFILL,[x2.jd[ok2],REVERSE(x2.jd[ok2])],[mdd+sdd,REVERSE(mdd-sdd)],color=14

 OPLOT,x2.jd[ok2],mdd

 OPLOT,x2.jd[ok2],dTb2[ok2]\*0.,LINESTYLE=2

 END

 IF plotvar EQ 'delta' THEN BEGIN

 mdd=dTb3-dTb2

 sdd=SQRT((sdTb3^2-sdTb2^2)>0) ;Catch NANs->0

 dmax=max([0.5\*abs([mdd+sdd\*2,mdd-sdd\*2]),0.1\*ymax]) ;Re-scale if needed

 PLOT,x3.jd,mdd,YTITLE='Delta Correction [K]',YRANGE=[-1,+1]\*dmax

 POLYFILL,[x3.jd,REVERSE(x3.jd)],[mdd+2\*sdd,REVERSE(mdd-2\*sdd)],color=15

 POLYFILL,[x3.jd,REVERSE(x3.jd)],[mdd+sdd,REVERSE(mdd-sdd)],color=14

 OPLOT,x3.jd,mdd

 OPLOT,x3.jd,dTb3\*0.,LINESTYLE=2

 END

 IF plotvar eq 'covar' THEN BEGIN

 plot,x1.jd,x1.covariance[i,\*]

 oplot,x2.jd,x2.covariance[i,\*],color=2

 oplot,x3.jd,x3.covariance[i,\*],color=3

 oplot,x0.jd,x0.covariance[i,\*],color=4

 ENDIF

 IF plotvar eq 'offset\_se' THEN BEGIN

 plot,x1.jd,x1.offset\_se[i,\*]

 oplot,x2.jd,x2.offset\_se[i,\*],color=2

 oplot,x3.jd,x3.offset\_se[i,\*],color=3

 oplot,x0.jd,x0.offset\_se[i,\*],color=4

 ENDIF

 IF plotvar eq 'slope\_se' THEN BEGIN

 plot,x1.jd,x1.slope\_se[i,\*]

 oplot,x2.jd,x2.slope\_se[i,\*],color=2

 oplot,x3.jd,x3.slope\_se[i,\*],color=3

 oplot,x0.jd,x0.slope\_se[i,\*],color=4

 ENDIF

 IF plotvar eq 'offset' THEN BEGIN

 plot,x1.jd,x1.offset[i,\*]

 oplot,x2.jd,x2.offset[i,\*],color=2

 oplot,x3.jd,x3.offset[i,\*],color=3

 oplot,x0.jd,x0.offset[i,\*],color=4

 ENDIF

 IF plotvar eq 'slope' THEN BEGIN

 plot,x1.jd,x1.slope[i,\*]

 oplot,x2.jd,x2.slope[i,\*],color=2

 oplot,x3.jd,x3.slope[i,\*],color=3

 oplot,x0.jd,x0.slope[i,\*],color=4

 ENDIF

 IF plotvar eq 'ncol' THEN BEGIN

 plot,x1.jd,x1.number\_of\_collocations[i,\*]

 oplot,x2.jd,x2.number\_of\_collocations[i,\*],color=2

 oplot,x3.jd,x3.number\_of\_collocations[i,\*],color=3

 oplot,x0.jd,x0.number\_of\_collocations[i,\*],color=4

 ENDIF

 IF plotvar EQ 'wt' THEN BEGIN

 PLOT, x0.jd,x0.w0a[i,\*],YTITLE='Weight',/NO\_DATA

 FOR k=0,4 DO $

 OPLOT,x0.jd,x0.ref\_wt[i,k,\*],COLOR=2+k

 ENDIF

 poly\_prop,reform(delta.coeff[i,\*]),reform(delta.covar[i,\*,\*]),rad,rad12,srad12

 dTb12=REFORM(msg\_rad2tb(Rad12,ich=i+1)-Tb0)

 sdTb12=REFORM(msg\_rad2tb(Rad12+sRad12,ich=i+1)-Tb0-dTb12)

 PRINT,chname[i],dTb12,sdTb12,$

 FORMAT='(a6," Delta(MetopB-A)=",f6.3," +/-",f6.3)'

ENDFOR

IF KEYWORD\_SET(crash) THEN STOP

!P.MULTI=0

!P.TITLE=''

!Y.TITLE=''

!X.TICKFORMAT = ''

!X.TICKUNITS = ''

!X.TICKINTERVAL = 0

!X.MINOR=0 ;30

!X.TICKLAYOUT = 0

!P.CHARSIZE=0

!X.STYLE=0

!P.THICK=0

!P.CHARTHICK=0

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

RETURN

END